	ГЛАВНАЯ	УСЛУГИ	ПЛАГИНЫ	КАРТЫ	REBUY	SCANMON	CASSA	SALE	ФОРУМ	МОНИТОР	HELP	КОНТАКТ

Team Voice Chat

Теги: Скачать плагины csСерверные

Плагин добавляет на сервер командный голосовой чат, который слышат только игроки в вашей команде

Компилятор: 1.9.0 REapi 265

Команды:

+teamvoice - Активирует team голосовой чат. Используется в виде бинда. Пример: bind "x" "+teamvoice"

.sma / .sp

#include <amxmodx>
#tryinclude <reapi>

// Если раскомментировано, живые НЕ будут слышать мёртвых, и наоборот
//#define OBEY_ALIVE_STATE

#if !defined _reapi_included
	#include <fakemeta>
#endif

#if AMXX_VERSION_NUM < 183
	#define client_disconnected client_disconnect
#endif

new g_iSpeakBitSum

public plugin_init() {
	register_plugin("Team Voice Chat", "0.1", "mx?!")

#if defined _reapi_included
	RegisterHookChain(RG_CSGameRules_CanPlayerHearPlayer, "CanPlayerHearPlayer_Pre")
#else
	register_forward(FM_Voice_SetClientListening, "OnSetClientListening_Pre")
#endif

register_clcmd("+teamvoice", "func_AdminVoiceOn")
	register_clcmd("-teamvoice", "func_AdminVoiceOff")
}

#if defined _reapi_included
	public CanPlayerHearPlayer_Pre(iReceiver, iSender) {
		if(!IsSpeak(iSender)) {
			return HC_CONTINUE
		}

SetHookChainReturn(ATYPE_BOOL, func_CheckListening(iReceiver, iSender) ? true : false)

return HC_SUPERCEDE
	}
#else
	public OnSetClientListening_Pre(iReceiver, iSender, bool:bCanHear) {
		if(!IsSpeak(iSender)) {
			return FMRES_IGNORED
		}

engfunc(EngFunc_SetClientListening, iReceiver, iSender, func_CheckListening(iReceiver, iSender) ? true : false)

return FMRES_SUPERCEDE
	}
#endif

bool:func_CheckListening(iReceiver, iSender) {
#if defined OBEY_ALIVE_STATE
	return (get_user_team(iReceiver) == get_user_team(iSender) && is_user_alive(iReceiver) == is_user_alive(iSender))
#else
	return (get_user_team(iReceiver) == get_user_team(iSender))
#endif
}

public func_AdminVoiceOn(id) {
	if(!IsSpeak(id)) {
		SetSpeak(id)
		client_cmd(id, "+voicerecord")
	}

return PLUGIN_HANDLED
}

public func_AdminVoiceOff(id) {
	if(IsSpeak(id)) {
		ClearSpeak(id)
		client_cmd(id, "-voicerecord")
	}

return PLUGIN_HANDLED
}

public client_disconnected(id) {
	ClearSpeak(id)
}

stock SetSpeak(id) (g_iSpeakBitSum |= (1 << id))
stock IsSpeak(id) return (g_iSpeakBitSum & (1 << id))
stock ClearSpeak(id) (g_iSpeakBitSum &= ~(1 << id))

Загрузил exec208

2023-06-20 21:06:42

Скачать

Данная иконка означает, что плагин был проверен администрацией хостинга на тестовом сервере, и проблем с ним не было выявлено. Рекомендуем ставить исключительно проверенные плагины.

Плагин загружен на сервер, но проверка еще не была проведена.

Игровые сервера	Дополнительные услуги		Инфо	Сообщество

Counter-Strike 1.6 Counter-Strike: Source Left 4 Dead 2 Counter-Strike: GO Garry's Mod Remote	VDS/VPS Dedicated Remote Вебхостинг CASSA	Scanmon Fast DL Backup	Help Тарифы Партнерка Новости Оферта	Форум Мониторинг Плагины^new vk.com steam Telegram